「M5StickC Plus」タグアーカイブ

M5StickC Plusで在宅勤務用の環境モニターを作った

コメントを残す

先日、M5StickC Plusを使ってCO2を測りました。この記事ではその続きとして、温度、湿度、気圧も測りました。

完成形

完成形はこちらです。M5EnvMonitorと名付けました。

ソースコードはGitHubで公開しています。

https://github.com/shoarai/M5EnvMonitor

開発過程

CO2の計測までは、以下の記事で紹介しています。

はじめてのM5StickC PlusでCO2を測った

追加の部品

M5Stack用環境センサユニットver.2(ENV II)
（秋葉原の千石電商で購入）

PlatformIOの環境構築

以前は開発環境としてArduino IDEを使っていたのですが、今回からPlatformIOとVisual Studio Code（VSCode）を使うことにしました。フォーマットの自動化やGitとの連携をしたかったのが理由です。

1. VSCodeと、PlatformIOというVSCode拡張機能をインストールする。

2. PlatformIOを開き、Home画面のNew Projectボタンから新規プロジェクトを作成する。

Name: プロジェクト名。ここではM5EnvMonitorとする。
Board：M5Stick-C（M5Stack）
Framework：Arduino
Location：任意のディレクトリ

これでプロジェクトが作成できました。この時点でGitを初期化、コミットしておきます。

Env IIの利用

Libraries画面で必要なプラグインを検索し、プロジェクトにインストールする。

ライブラリのインストールは、platform.ioファイルのlib_depsに直接記載することも可能です。また、Arduinoライブラリとして公開されていなくても、GitHubで公開されているライブラリをインストールすることもできます。以下の最後の行のように、GitHubのURLを記載すればOKです。

[env:m5stick-c]
platform = espressif32
board = m5stick-c
framework = arduino
lib_deps =
	m5stack/M5StickCPlus@^0.0.2
	adafruit/Adafruit Unified Sensor@^1.1.4
	adafruit/Adafruit BMP280 Library@^2.4.2
	ambientdatainc/Ambient ESP32 ESP8266 lib@^1.0.1
	https://github.com/nara256/mhz19_uart

ENV IIの利用

ENV IIのサンプルコードを使って、ENV IIの測定値を表示します。Adafruit_Sensor.hはAdafruit Unified Sensorライブラリに含まれていたので、ライブラリをインストールしました。ENVII.inoの内容をsrc/main.cppコピーしてビルド、アップロードします。

カスタマイズ

計測値の表示レイアウトを調整したり、M5StickC Plusの情報表示を追加しました。
※CO2センサーが壊れているので、繋いでいない状態です；なのでCO2は-1になってます。

画面仕様は以下の通り。

画面右上：充電状態。”Full”は満充電。”USB”は充電中。
画面右上：電池の残量。
画面左の色：測定値が快適かどうか。緑なら問題なし。赤は問題あり。
　　　　　　・17℃ < 温度 < 28℃なら緑、それ以外は赤
　　　　　　・40% < 湿度 < 60なら緑、それ以外は赤
画面右下：Ambientへのデータ送信の結果。成功なら表示なし、失敗なら”Send NG”

使っていくうちにまたいろいろ変えるかもしれません。

M5StickC PlusとAmbientでCO2の推移を可視化した

コメントを残す

前回の記事では、M5StickC PlusとMH-Z19CでCO2濃度を測定し、画面に表示しました。今回は、CO濃度の推移をチャートで見れるようにするため、測定値をクラウドに蓄積して可視化してみました。

はじめてのM5StickC PlusでCO2を測った

クラウドサービス

データを蓄積するクラウドサービスはAmbientを使いました。無料枠でも、8チャネル×8種類のデータ、データの保存期間1年間と、個人で使うには十分すぎるサービスです。有料版は、データの受信監視や通知が利用できるようです。

クラウドサービスなので、M5StickC Plusからデータを送信するには、インターネットに繋がるWiFiのアクセスポイントが必要です。

セットアップ

Ambient公式ドキュメントの以下の手順で、チャネル生成まで行います。

ユーザー登録(無料)
チャネル生成

生成したチャネルの「チャネル設定」で、以下の通りデータ名を変更しておきます。

データー1：CO2
データー2：温度

Ambientのライブラリは、Arduino IDEのメニューバーの「ツール → ライブラリを管理…」で、「ambient」と検索すると見つかります。ライブラリ名は「Ambient ESP32 ESP8266 lib」です。バージョンは1.0.1でした。

ソースコードの更新

前回の記事のソースコードに、以下のコメント部分を追記します。「…」の部分は各自の環境に合わせて、WiFiのアクセスポイントの情報と、生成したチャネルのチャネルIDとライトキーを記載します。

	#include <M5StickCPlus.h>
	#include <MHZ19_uart.h>

	// Ambientライブラリをインクルードする。
	#include "Ambient.h"

	const int rx_pin = 36;
	const int tx_pin = 26;

	// WiFiアクセスポイントのSSIDとパスワードを設定する。
	const char* ssid = "...";
	const char* password = "...";

	// Ambientで作ったチャネルのチャネルIDとライトキーを設定する。
	unsigned int channelId = ...;
	const char* writeKey = "...";

	MHZ19_uart mhz19;

	// WiFiとAmbientの変数を宣言する。
	WiFiClient client;
	Ambient ambient;

	void setup()
	{
	M5.begin();
	pinMode(36, INPUT);
	gpio_pulldown_dis(GPIO_NUM_25);
	gpio_pullup_dis(GPIO_NUM_25);

	Serial.begin(9600);
	mhz19.begin(rx_pin, tx_pin);
	mhz19.setAutoCalibration(false);

	M5.Lcd.setRotation(3);
	M5.Lcd.setTextSize(4);

	// Wi-Fiアクセスポイントに接続する。
	WiFi.begin(ssid, password);
	while (WiFi.status() != WL_CONNECTED) {
	delay(100);
	}
	M5.Lcd.println("WiFi connected.");

	// Ambientを初期化する。
	ambient.begin(channelId, writeKey, &client);

	M5.Lcd.println("MH-Z19 is warming up now.");
	delay(10 * 1000);
	}

	void loop()
	{
	int co2ppm = mhz19.getCO2PPM();
	int temp = mhz19.getTemperature();

	M5.Lcd.fillScreen(BLACK);
	M5.Lcd.setCursor(0, 0);

	M5.Lcd.print("co2: ");
	M5.Lcd.println(co2ppm);
	M5.Lcd.print("temp: ");
	M5.Lcd.println(temp);

	// 測定値をAmbientに送信する。
	ambient.set(1, co2ppm);
	ambient.set(2, temp);
	ambient.send();

	delay(5000);
	}

view raw MHZ19_sendco2_ambient.ino hosted with ❤ by GitHub

チャートの確認

Ambientでデータを送信したチャネルを開くと、CO2濃度の推移を可視化できました！
左のCO2のチャートを見ると、15:30:00過ぎに600ppmぐらいまで下がっています。これはエアコンをつけて窓を締め切った部屋から、ベランダに出たためです。

はじめてのM5StickC PlusでCO2を測った

コメントを残す

先日はじめてギターアンプを自作しましたが、今回はM5StickC Plusを使った電子工作です。在宅勤務が今後も続きそうなので、自宅の快適さを測りたいと思い、集中力に影響があると言われているCO2の濃度を測ることにしました。

デバイスと部品

M5StickC Plus：秋月電子で購入
MH-Z19C：秋月電子で購入
ジャンプワイヤーオス-メス：以前Amazonで購入したもの

MH-Z19Bという下位バージョンのものもありますが、フェイク品が出回っているそうで、秋月で確実に買えるMH-Z19Cにしました。その他にPC、PCとM5StickC Plusを繋ぐためのUSB Type−Cケーブルが必要です。

環境構築

Arduino IDEをインストールしてセットアップ

Arduino IDEのインストールやセットアップは、Interfaceの以下の記事を参考にしました。実施するのはステップ1、2だけです。
M5StickC Plusの開発環境（Arduino IDE）構築の手順 – Interface

記事ではWindows10で、僕はMacで実施しましたが問題ありませんでした。Macの場合は、zipファイルがダウンロードされ、解凍するとappファイルができます。また、記事中にある「ESP32パッケージのJSONファイルURL」は以下になります。コピペ用にどうぞ。
https://dl.espressif.com/dl/package_esp32_index.json

バージョンは以下の通り。

Arduino IDE：1.8.15
ESP32パッケージ：1.0.6

PlatformIOという開発環境もあるようですが、初心者なのでまずは基本的な環境であるArduino IDEを使ってみます。

サンプルプログラムの実行

試しにサンプルプログラムを動かしてみます。メニューバーの「ファイル → スケッチ例 → M5StickCPlus → Basics → IMU」を選ぶと、サンプルプログラムのソースコードが表示されます。画面左上の「マイコンボードに書き込む」ボタンを押して、プログラムをマイコンに書き込みます。IMUというのは加速度センサーのサンプルです。

初めて書き込みを実行したときは、「シリアルポートが選択されていません。」というエラーが表示されました。「cu.usbserial-…」というポートを選んで再度実行したところ、正常に書き込め、プログラム実行できました。

CO2濃度の計測

M5StickC PlusとMH-Z19Cを接続します。以下のピン同士をジャンプワイヤーオス-メスで繋げます。

M5StickC Plusのピン	MH-Z19Cのピン
GND	GND
5V→	VIN
G26	Rx
G36（G36/G25と記載されているピン）	Tx

プログラムにはmhz19_uartというライブラリを使わせてもらいます。zipファイルをダウンロードし、メニューバーの「スケッチ → ライブラリのインクルード → .ZIP形式のライブラリをインストール…」からインストールします。

このライブラリには実行サンプルコードも付属しているので、使わせてもらいましょう。メニューバーの「ファイル → スケッチ例 → MHZ19_uart → MHZ19_getco2」を選ぶと、サンプルコードが表示されます。ただし、まだマイコンに書き込みません。下記のコメント記載部分を追記、変更してからマイコンに書き込みます。

	//　追記：M5StickC Plusで必要なヘッダをインクルードする。
	#include <M5StickCPlus.h>
	#include <MHZ19_uart.h>

	// 変更：接続するピンの番号を変更する。
	const int rx_pin = 36;
	const int tx_pin = 26;

	MHZ19_uart mhz19;

	void setup()
	{
	// 追記：M5StickC Plusの初期化と、G36ピンを使うためにG25ピンをフローティングにする。
	M5.begin();
	pinMode(36, INPUT);
	gpio_pulldown_dis(GPIO_NUM_25);
	gpio_pullup_dis(GPIO_NUM_25);

	Serial.begin(9600);
	mhz19.begin(rx_pin, tx_pin);
	mhz19.setAutoCalibration(false);

	// 追記：デフォルトだと画面が見づらいので、横向き表示でフォントを大きくする。
	M5.Lcd.setRotation(3);
	M5.Lcd.setTextSize(4);

	// 変更：文字を画面に表示する。
	M5.Lcd.println("MH-Z19 is warming up now.");
	delay(10 * 1000);
	}

	void loop()
	{
	int co2ppm = mhz19.getCO2PPM();
	int temp = mhz19.getTemperature();

	// 追記：画面の表示とカーソルを初期化することで、前回の文字の表示を消す。
	M5.Lcd.fillScreen(BLACK);
	M5.Lcd.setCursor(0, 0);

	// 変更：文字を画面に表示する。
	M5.Lcd.print("co2: ");
	M5.Lcd.println(co2ppm);
	M5.Lcd.print("temp: ");
	M5.Lcd.println(temp);

	delay(5000);
	}